O NTC 10k e o logaritmo

Na aula 1, o LM35 entregava tensão pronta e a conta eram dois passos. Só que o LM35 custa mais caro, vai até 100 °C e não gosta de água. Quando você abre um chuveiro, uma geladeira, uma estufa ou um ar-condicionado, o que está lá dentro é quase sempre um NTC: uma pontinha de metal com dois fios. E ele não mede nada sozinho.

O NTC muda de resistência com o calor: esquentou, a resistência cai. A 25 °C vale 10.000 Ω, por isso “10k”. O Arduino não mede resistência, só tensão. Então a gente monta um divisor de tensão.

A peça por fora

O divisor de tensão

A mesma conta, dentro do Arduino

O log() do Arduino é o logaritmo natural, o mesmo ln da equação. A linha de guarda no começo existe porque leitura 0 ou 1023 faria a conta dividir por zero:

const int PINO = A0;
const float R  = 10000.0;   // o resistor fixo
const float R0 = 10000.0;   // o NTC a 25 graus
const float T0 = 298.15;    // 25 graus em kelvin
const float BETA = 3950.0;  // do fabricante

void setup() {
  Serial.begin(9600);
}

void loop() {
  int leitura = analogRead(PINO);
  if (leitura < 5 || leitura > 1018) {      // fio solto ou curto
    Serial.println("leitura fora da faixa");
    delay(500);
    return;
  }

  float rntc   = R * leitura / (1023.0 - leitura);   // passo 1
  float kelvin = 1.0 / (1.0 / T0 + log(rntc / R0) / BETA);
  float graus  = kelvin - 273.15;                    // passo 2

  Serial.print(leitura);   Serial.print("  ");
  Serial.print(rntc, 0);   Serial.print(" ohm  ");
  Serial.println(graus, 1);
  delay(500);
}